ドロップルールからPipeline cloudルールに移行する

重要

2025 年 5 月 21 日以降、新規顧客はNRQLドロップルールを使用できなくなります。 NRQL ドロップルールは 2026 年 1 月 7 日に終了します。

データ削除ルールを引き続き管理するには、 Pipeline クラウドルールに移行します。

newrelic_nrql_drop_ruleリソースを使用して Terraform 経由で NRQL ドロップルールを管理している場合は、それらをnewrelic_pipeline_cloud_ruleリソースに移行する必要があります。New Relic は基礎となるドロップルールをすでに移行していますが、Terraform は独自の状態ファイルを維持し、明示的に構成したリソースのみを認識します。Terraform はこれらを 2 つの完全に異なるリソースタイプとして扱うため、 Pipeline cloudルールを Terraform の状態にインポートし、古いドロップルールリソースを削除する必要があります。

移行アプローチ

このガイドでは、Terraform でNRQLドロップルールをPipeline cloudルールに移行する 2 つの方法について説明します。

ネイティブ Terraform コマンド: terraform import 、 terraform plan 、およびterraform state rmコマンドを使用する標準の Terraform ワークフロー。
New Relic CLI 自動化ツール: New Relic は、ネイティブ Terraform ワークフローを自動化する CLI ツールを提供しており、次の 2 つのバージョンがあります。
- GitOps (CI/CD): Terraform の状態がワークスペースから直接アクセスできない (通常はリモートバックエンドに保存される) CI/CD ツールを使用するチーム向け。
- ローカル Terraform: ローカルまたはリモートバックエンドにある Terraform 状態ファイルを直接読み取ることができる Terraform コマンドを実行するチーム向けです。

手作業とエラーの可能性を大幅に削減できるため、New Relic の自動化ツールを使用することをお勧めします。ただし、完全な制御を希望する場合や特定の要件がある場合は、ネイティブの Terraform コマンドアプローチに従うことができます。

ネイティブの Terraform コマンドを使用して移行する

このセクションでは、ネイティブ Terraform コマンドを使用してnewrelic_nrql_drop_ruleリソースからnewrelic_pipeline_cloud_ruleリソースに移行するための標準の Terraform ワークフローについて説明します。このセクションのすべてのコマンドは、ドロップルール設定が配置されている Terraform 作業ディレクトリから実行する必要があります。

前提条件

Terraform または OpenTofu v1.5 以上:このバージョンでは、 importブロック機能が導入され、リソース設定を手動で記述する必要がなくなり、移行プロセスがより効率的になりました。
New Relic Terraform Provider v3.73.0 以上:この推奨バージョンでは、 newrelic_pipeline_cloud_ruleリソースとnewrelic_nrql_drop_ruleリソースのpipeline_cloud_rule_entity_id属性 (2025 年 9 月にリリースされた v3.68.0 で追加) を使用して、Terraform 経由でPipeline cloudルールを管理するためのサポートが拡張され、スムーズな移行プロセスを保証するための重要なバグ修正が含まれています。

移行の手順

Pipeline cloudルールIDを取得する

Terraform 作業ディレクトリで New Relic Terraform Provider を v3.73.0 以上にアップグレードしてから、 terraform applyを実行して既存のnewrelic_nrql_drop_ruleリソースを更新します。この操作では、 New Relicによって自動的に作成された対応するPipeline cloudルールの ID を含むpipeline_cloud_rule_entity_idプロパティを追加して、Terraform の状態を更新します。

注記

より安全な操作を行うには、 -refresh-onlyフラグを使用してインフラストラクチャを変更せずに状態を更新するか、 -targetを使用して操作を特定のドロップルールリソースに制限します。

Terraform 作業ディレクトリに移動し、次のいずれかのコマンドを実行します。

bash

$# Apply to update state with pipeline_cloud_rule_entity_id
$  terraform apply
$
$  # Safer: use refresh-only to see changes without modifying infrastructure
$  terraform apply -refresh-only
$
$  # Targeted: limit operation to specific drop rule resources
$  terraform apply -refresh-only -target=newrelic_nrql_drop_rule.foo

上記のコマンドのいずれかを実行すると、各ドロップルールに対してpipeline_cloud_rule_entity_idが使用可能になります。次のステップで使用するために ID を手元に置いておきます。

# Example: Get the Pipeline cloud rule ID for a drop rule
newrelic_nrql_drop_rule.foo.pipeline_cloud_rule_entity_id

Pipeline cloudルールをTerraform状態にインポートする

Terraform 作業ディレクトリに新しい.tfファイル (たとえば、 import_pipeline_rules.tf ) を作成します。このファイルでは、移行するドロップルールごとにインポートブロックを追加します。前の手順のpipeline_cloud_rule_entity_id値を使用します。

# import_pipeline_rules.tf
# Create import block using the pipeline_cloud_rule_entity_id from state
import {
  to = newrelic_pipeline_cloud_rule.foo
  # Reference the ID from the drop rule resource
  id = newrelic_nrql_drop_rule.foo.pipeline_cloud_rule_entity_id

  # Or use the actual value from your state
  # id = "MzgwNjUyNnxOR0VQfFBJUEVMSU5FX0NMT1VEX1JVTEV8MDE5OTRjZjgtYmFmNy03MjU3LWE3M2MtZWY5OTkxYTQxMjgy"
}

次に、Terraform 作業ディレクトリから Terraform コマンドを実行して設定を生成し、インポートします。

bash

$# Generate Pipeline cloud rule configuration automatically
$terraform plan -generate-config-out=generated_pipeline_rules.tf
$
$# Apply to import the Pipeline cloud rules
$terraform apply

Terraform 状態から古いドロップルールリソースを削除します。

Pipeline cloudルールを正常にインポートした後、 terraform state rmコマンドを使用して、Terraform 状態からnewrelic_nrql_drop_ruleリソースへのすべての参照を削除する必要があります。

bash

$terraform state rm newrelic_nrql_drop_rule.foo

これにより、New Relic からは削除されずに、Terraform 状態からドロップルールが削除されます。

ヒント

また、Terraform のremovedブロック( Terraform v1.7 以降で使用可能) を使用して、設定ファイル内で宣言的に状態からリソースを削除することもできます。

Terraform 設定をクリーンアップする

Terraform 状態からドロップルールを削除した後、Terraform 設定ファイルからすべてのnewrelic_nrql_drop_ruleリソースブロックをコメントアウトし、これらのドロップルールに依存する補助リソースをすべて削除する必要があります。

次に、 terraform planを実行して移行を確認します。

bash

$terraform plan

移行が成功した場合、出力には「変更なし」と表示されます。

New Relicの自動化ツールで移行する

上記のネイティブ Terraform 移行ワークフローを簡素化するために、New Relic はインポートと状態管理を処理する CLI 自動化ツールを提供しています。これらのツールは、同じ基礎となる Terraform 操作 (インポート、計画、適用、状態の削除) を自動化しますが、手作業は大幅に少なくなります。

前提条件

Terraform または OpenTofu v1.5 以上:自動移行アプローチに必要です。
New Relic Terraform Provider v3.73.0 以上:この推奨バージョンでは、 newrelic_pipeline_cloud_ruleリソースとnewrelic_nrql_drop_ruleリソースのpipeline_cloud_rule_entity_id属性 (2025 年 9 月にリリースされた v3.68.0 で追加) を使用して、Terraform 経由でPipeline cloudルールを管理するためのサポートが拡張され、スムーズな移行プロセスを保証するための重要なバグ修正が含まれています。
New Relic CLI:自動移行コマンドを実行するために必要です。
環境変数:
- NEW_RELIC_API_KEY - 適切な権限を持つNew RelicユーザーAPIキー。
- NEW_RELIC_ACCOUNT_ID - ドロップルールが配置されている New Relic アカウント ID。
- NEW_RELIC_REGION (オプション) - アカウントの地域に基づいて「US」または「EU」に設定します (デフォルトは「US」)。

アプローチを選択する

GitOps の自動化プロセスでは、状態ファイルに簡単にアクセスできない CI/CD 環境向けに設計された 3 フェーズのアプローチを使用します。これらのフェーズにより、新しいPipeline Cloud Rule ID の安全な抽出、設定ファイルの生成、パイプライン内の状態のインポートとクリーンアップが確実に実行されます。

このフェーズでは、既存のドロップルールを識別し、その考えを構造化された JSON データとしてエクスポートする検証スクリプトをCI/CD Terraform 設定に追加します。

重要

この手順は、一度に 1 つのワークスペース (一度に 1 つの Terraform 状態ファイル) に適用されます。ドロップルールが設定されたワークスペースが複数ある場合は、ワークスペースごとにこのプロセスを繰り返します。

検証スクリプトをダウンロードして追加する

New Relic Terraform Provider GitHub リポジトリからoutputs.tfファイルをダウンロードし、CI/CD Terraform ワークスペースに追加します。

このスクリプトは、ドロップルールリソースの検証および抽出システムを提供し、移行手順で使用するために JSON 形式で ID を出力します。

ドロップルールの種類に応じてスクリプトを構成する

スクリプトは、次の 2 種類のドロップルールをサポートしています。

スタンドアロンドロップルール: newrelic_nrql_drop_ruleリソースは設定で直接定義されています (モジュールにラップされていません)
モジュラードロップルール: Terraform モジュール内にラップされたnewrelic_nrql_drop_ruleのリソース
追加したoutputs.tfファイルで、 localsブロックに適切なフラグを設定して、ドロップルールタイプの処理を有効にします。
```
locals {
  # Enable for standalone drop rules
  enable_standalone_drop_rules = true

  # Enable for modular drop rules
  enable_modular_drop_rules = false
}
```
スタンドアロンのドロップルールがある場合は、 enable_standalone_drop_rulesをtrueに設定します。モジュラードロップルールがある場合は、 enable_modular_drop_rulesをtrueに設定します。両方のタイプがある場合は、両方を有効にできます。

スタンドアロンのドロップルールを追加します（該当する場合）

スタンドアロンのドロップルールがあり、前の手順で有効にした場合は、Terraform 設定ですべてのスタンドアロンnewrelic_nrql_drop_ruleリソースを識別します。

たとえば、Terraform 設定に次のスタンドアロンドロップルールがあるとします。

resource "newrelic_nrql_drop_rule" "drop_debug_logs" {
  account_id  = var.new_relic_account_id
  description = "Filters out debug level logs"
  action      = "drop_data"
  nrql        = "SELECT * FROM Log WHERE level = 'debug'"
}

resource "newrelic_nrql_drop_rule" "drop_health_checks" {
  account_id  = var.new_relic_account_id
  description = "Removes health check logs"
  action      = "drop_data"
  nrql        = "SELECT * FROM Log WHERE endpoint = '/health'"
}

resource "newrelic_nrql_drop_rule" "drop_pii_data" {
  account_id  = var.new_relic_account_id
  description = "Filters out PII data"
  action      = "drop_data"
  nrql        = "SELECT * FROM Log WHERE contains(message, 'SSN')"
}

各リソースについて、リソース識別子と完全なリソース参照をメモする必要があります。たとえば、リソースnewrelic_nrql_drop_rule.drop_debug_logsの場合:

リソース識別子は drop_debug_logs
完全なリソース参照は newrelic_nrql_drop_rule.drop_debug_logs

outputs.tfファイルで、指定されたスタンドアロンドロップルールセクションのstandalone_rulesリストに次のリソースを追加します。

# Configure standalone drop rules here
standalone_rules = local.enable_standalone_drop_rules ? [
  {
    name     = "drop_debug_logs"
    resource = newrelic_nrql_drop_rule.drop_debug_logs
  },
  {
    name     = "drop_health_checks"
    resource = newrelic_nrql_drop_rule.drop_health_checks
  },
  {
    name     = "drop_pii_data"
    resource = newrelic_nrql_drop_rule.drop_pii_data
  }
] : []

注記

nameフィールドはリソース識別子と一致する必要があり、 resourceフィールドは完全なリソース参照と一致する必要があります。countまたはfor_eachメタ引数を使用して作成されたドロップルールリソースの場合は、リソース識別子 (たとえば、 newrelic_nrql_drop_rule.drop_health_checks[0]またはnewrelic_nrql_drop_rule.drop_health_checks["key_1"] ) を明示的にインデックスします。CI/CD 環境で状態アクセス権がある場合は、次の bash コマンドを使用してリスト形式を自動的に生成できます (これは実験的なものであり、特定の状態構造に基づいて調整が必要になる場合があります)。

bash

$terraform state list | \
>  grep 'newrelic_nrql_drop_rule' | \
>  grep -v '^module\.' | \
>  sed -E \
>    -e '/\.([^[]+)\["/ s/^.*\.([^[]+)\["([^"]+)"\].*$/  {\n    name     = "\1_\2"\n    resource = &\n  },/' \
>    -e 't' \
>    -e '/\.([^[]+)\[[0-9]/ s/^.*\.([^[]+)\[([0-9]+)\].*$/  {\n    name     = "\1_\2"\n    resource = &\n  },/' \
>    -e 't' \
>    -e 's/^.*\.([^ ]+)$/  {\n    name     = "\1"\n    resource = &\n  },/'

terraformコマンドは、Terraform ラッパーまたは同等の GitOps ツールに置き換える必要がある場合があります。

モジュラードロップルールを追加します（該当する場合）

モジュラードロップルールがあり、手順 2 で有効にした場合は、モジュールをスクリプトに追加する前に、モジュールがall_rules属性をエクスポートしていることを確認する必要があります。

前提条件: モジュールは、モジュールによって管理されるすべてのnewrelic_nrql_drop_ruleリソースへの参照を保持する属性all_rulesをエクスポートする必要があります。

上記の手順で説明したのと同じ 3 つのドロップルールがある場合は、次の出力をモジュールに追加します。

output "all_rules" {
  description = "A map of all drop rule resource objects created by this module."
  value = {
    debug_logs    = newrelic_nrql_drop_rule.drop_debug_logs
    health_checks = newrelic_nrql_drop_rule.drop_health_checks
    pii_data      = newrelic_nrql_drop_rule.drop_pii_data
  }
}

次に、 outputs.tfファイルで、指定されたモジュラードロップルールセクションの_modular_rules_rawリストにモジュールを追加します。

# Configure modular drop rules here
_modular_rules_raw = local.enable_modular_drop_rules ? [
  {
    name     = "production_drop_rules"
    resource = module.drop_rules["production_drop_rules"].all_rules
  }
] : []

注記

CI/CD 環境で状態アクセス権がある場合は、次の bash コマンドを使用して、モジュラールールのリスト形式を自動的に生成できます (これは実験的なものであり、状態構造に基づいて調整が必要になる場合があります)。

bash

$terraform state list | \
>  grep '^module\..*newrelic_nrql_drop_rule' | \
>  sed -E 's/(\.newrelic_nrql_drop_rule.*)//' | \
>  sort -u | \
>  sed -E 's/^module\.([^[]+)\["([^"]+)"\]$/  {\n    name     = "\2"\n    resource = module.\1\["\2"].all_rules\n  },/'

terraformコマンドは、Terraform ラッパーまたは同等の GitOps ツールに置き換える必要がある場合があります。

terraform planを実行する

CI/CD 環境で、次のコマンドを実行します。

bash

$terraform plan

計画が成功した場合、出力に成功メッセージが表示されます。

Changes to Outputs:
  + a_validation_success = "✅ All listed resources export pipeline_cloud_rule_entity_id"

これにより、すべてのドロップルールリソースが正しく構成され、 pipeline_cloud_rule_entity_id属性がエクスポートされることが確認されます。これで、 terraform apply実行に進むことができます。

次のような検証エラーが表示された場合:

Changes to Outputs:
  + validation_errors = [
      + "❌ Drop rule 'drop_debug_logs' does not export `pipeline_cloud_rule_entity_id` or it is null",
      + "❌ Drop rule 'drop_health_checks' does not export `pipeline_cloud_rule_entity_id` or it is null",
      + "❌ Drop rule 'drop_pii_data' does not export `pipeline_cloud_rule_entity_id` or it is null",
    ]

これは、New Relic Terraform Provider >= v3.73.0 を使用していないことを意味します。Terraform 設定でプロバイダーのバージョンを v3.73.0 以上にアップグレードしてから、 terraform plan再度実行してください。

terraform applyを実行する

計画の出力に成功メッセージが表示されていることを確認したら、次を実行します。

bash

$terraform apply

適用が正常に完了すると、次のような出力が表示されます。

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

Outputs:

a_validation_success = "✅ All listed resources export pipeline_cloud_rule_entity_id"
experimental_drop_rule_resource_ids = "{\"drop_rule_resource_ids\":[{\"id\":\"3806526:106878882\",\"name\":\"drop_debug_logs\",\"pipeline_cloud_rule_entity_id\":\"MzgwNjUyNnxORVVMS...\"},{\"id\":\"3806526:106878883\",\"name\":\"drop_health_checks\",\"pipeline_cloud_rule_entity_id\":\"MzgwNjUyNnxORVVMS...\"},{\"id\":\"3806526:106878884\",\"name\":\"drop_pii_data\",\"pipeline_cloud_rule_entity_id\":\"MzgwNjUyNnxORVVMS...\"}]}"
experimental_drop_rule_resource_ids_formatted = <<EOT
{
  "drop_rule_resource_ids": [
    {
      "name": "drop_debug_logs",
      "id": "3806526:106878882",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    },
    {
      "name": "drop_health_checks",
      "id": "3806526:106878883",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    },
    {
      "name": "drop_pii_data",
      "id": "3806526:106878884",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    }
  ]
}
EOT

JSON出力をコピーする

experimental_drop_rule_resource_ids_formatted出力から JSON 文字列全体をコピーします。フェーズ 2 ではこれが必要になります。

このフェーズでは、 New Relic CLI を使用して、フェーズ 1 の JSON 出力に基づいて、 Pipeline cloudルールの Terraform 設定ファイルを自動的に生成します。

必要な環境変数を設定する

CLI コマンドを実行する前に、必要な環境変数が設定されていることを確認してください。

bash

$export NEW_RELIC_API_KEY="your-api-key"
$export NEW_RELIC_ACCOUNT_ID="your-account-id"
$export NEW_RELIC_REGION="US"  # Optional, defaults to 'US'

JSON出力をファイルに保存する

Terraform ワークスペースディレクトリに JSON ファイル (例: drop_rules.json ) を作成し、フェーズ 1 からの JSON 出力を貼り付けます。

{
  "drop_rule_resource_ids": [
    {
      "name": "drop_debug_logs",
      "id": "3806526:106878882",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    },
    {
      "name": "drop_health_checks",
      "id": "3806526:106878883",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    },
    {
      "name": "drop_pii_data",
      "id": "3806526:106878884",
      "pipeline_cloud_rule_entity_id": "MzgwNjUyNnxORVVMS..."
    }
  ]
}

New Relic CLI移行コマンドを実行する

Terraform ワークスペースディレクトリに移動して、次のコマンドを実行します。

bash

$newrelic migrate nrqldroprules tf-importgen-ci --file drop_rules.json

ヒント

簡単にするために、JSON ファイルが存在する Terraform ワークスペースディレクトリでこのコマンドを直接実行し、個別の--workspacePathを指定する必要がないようにすることをお勧めします。

コマンド:

パラメータ	タイプ	説明	必須
- ファイル	弦	ステップ 1 のドロップルールマッピングを含む JSON ファイルへのパス。 `--file` または `--json` いずれかを指定する必要がありますが、両方を指定することはできません。	はい*
--json	弦	ドロップルールマッピングを含む JSON 文字列。 `--file` の代替。	はい*
--ワークスペースパス	弦	Terraform ワークスペースへのパス。省略した場合は現在のディレクトリがデフォルトになります。	いいえ
- 豆腐	ブール値	Terraform の代わりに OpenTofu を使用している場合に使用します。	いいえ

--jsonを使用した例:

ファイルを作成したくない場合は、JSON 文字列を直接渡すことができます。

bash

$newrelic migrate nrqldroprules tf-importgen-ci \
>  --json '{"drop_rule_resource_ids":[{"name":"drop_debug_logs","id":"3806526:106878882","pipeline_cloud_rule_entity_id":"MzgwNjUyNnxORVVMS..."}]}'

/ <Step> #### コマンドの実行内容を理解する [#understand-command-execution] tf-importgen-ci コマンドは、次のアクションを自動的に実行します。 - 入力と環境変数を検証します - 環境と入力データ間のアカウント ID の一貫性を確認します - Terraform/OpenTofu インストレーションとバージョンを検証します (v1.5+ が必要) - ワークスペースディレクトリを作成または検証します - プロバイダー設定 (provider.tf) を生成します - インポートブロック (imports.tf) を生成します - Terraform/OpenTofu ワークスペースを初期化します - terraform plan を実行してPipeline cloudルール設定 (pcrs.tf) を生成します - すべての設定ファイルをフォーマットします - フェーズ 3 の推奨事項を提供します (状態から古いドロップルールを削除します) <Callout variant="important"> アカウント ID の検証: このコマンドは、JSON データ内のアカウント ID が NEW_RELIC_ACCOUNT_ID 環境変数と一致することを自動的に検証します。不一致が検出されると、インポートの失敗の可能性に関する警告が表示されます。</Callout> <Callout title="注記"> 重複するリソース名: 入力データ内に重複するリソース名が見つかった場合、コマンドはランダムなアルファベットのサフィックスを追加して重複するリソース名を自動的に解決し、リソース定義が一意になるようにします。</Callout> </Step> /

生成されたファイルを確認する

CLI コマンドは、ワークスペースに 3 つの Terraform 設定ファイルを生成します。

provider.tf :バージョン制約のある Terraform およびNew Relicプロバイダーの設定。
imports.tf : New Relic内の既存のPipeline cloudルールに新しいリソースをリンクするブロックをインポートします。
pcrs.tf : Pipeline cloudルールのリソース定義 (コマンド実行中に自動生成されます)。
このコマンドは、フェーズ 3 で使用する、Terraform 状態から古いドロップルールを削除するための推奨事項も表示します。

生成した設定をコミットしてプッシュする

生成された Terraform ファイルを Git リポジトリに追加します。

bash

$git add .
$git commit -m "Add Pipeline cloud rule migration configuration"
$git push origin your-branch-name

これによりCI/CDパイプラインがフェーズ 3 の変更を処理するようになります。

このフェーズでは、 CI/CDパイプラインはフェーズ 2 でプッシュした変更を処理し、 Pipeline cloudルールを Terraform 状態にインポートし、古いドロップルールリソースを削除します。

Terraformプランを確認する

変更をプッシュすると、 CI/CDパイプラインが自動的にトリガーされ、プルリクエストにプランコメントが投稿されます。計画の出力には次の内容が表示されます。

インポート中のリソース: 3 つのnewrelic_pipeline_cloud_ruleリソース
プラン概要: Plan: 3 to import, 0 to add, 0 to change, 0 to destroy
/ Terraformプランの出力例: diff Terraformは次のアクションを実行します: # newrelic_pipeline_cloud_rule.drop_debug_logsがインポートされます resource "newrelic_pipeline_cloud_rule" "drop_debug_logs" { account_id = 3806526 description = "Filters out debug level log from honban environment to reduce data volume" id = "MzgwNjUyNnxOR0VQfFBJUEVMSU5FX0NMT1VEX1JVTEV8MDE5OTRjZjgtYmFmNy03MjU3LWE3M2MtZWY5OTkxYTQxMjgy" name = " NRQLドロップルールID: 106878882 作成者: ユーザーID: 1004672904 作成場所: 2025-09-15T10:43:13.122888Z" NRQL = "DELETE FROM `log` WHERE ((`level` = 'debug') AND (`environment` = 'production'))" } # newrelic_pipeline_cloud_rule.drop_health_checks がインポートされます resource "newrelic_pipeline_cloud_rule" "drop_health_checks" { account_id = 3806526 description = "MyCustomEventデータからuserEmailとuserName属性を削除します" id = "MzgwNjUyNnxOR0VQfFBJUEVMSU5FX0NMT1VEX1JVTEV8MDE5OTRjZmItMTQ0Yy03NDM5LWJhNDYtZjI4MTg0ODc5YmE2" name = " NRQLドロップルールID: 106878884 作成者ユーザー ID: 1004672904 作成日: 2025-09-15T10:45:47.049993Z" NRQL = "DELETE `userEmail`, `userName` FROM `MyCustomEvent`" } # newrelic_pipeline_cloud_rule.drop_pii_data になりますインポートされたリソース "newrelic_pipeline_cloud_rule" "drop_pii_data" { account_id = 3806526 description = "メトリクス集計からcontainerIdプロパティを除外します" id = "MzgwNjUyNnxOR0VQfFBJUEVMSU5FX0NMT1VEX1JVTEV8MDE5OTRjZmItMTQ4Ni03MDI4LWJlMDktZmYzOTM2NWQ4ODUw" name = " NRQLドロップルール ID: 106878885、作成者: ユーザー ID: 1004672904、作成日時: 2025-09-15T10:45:47.060296Z" NRQL = "DELETE `containerId` FROM `MetricAggregate`" } プラン: インポート 3、追加 0、変更 0、破棄 0。 /

変更を適用する

計画を確認し、正しいことを確認したら、プルリクエストにコメントしてください。

bash

$terraform apply

CI/CDパイプラインは Terraform 適用を実行し、 Pipeline cloudルールを Terraform 状態にインポートします。

適用出力のサンプル:

newrelic_pipeline_cloud_rule.drop_health_checks: Importing...
newrelic_pipeline_cloud_rule.drop_health_checks: Import complete
newrelic_pipeline_cloud_rule.drop_debug_logs: Importing...
newrelic_pipeline_cloud_rule.drop_debug_logs: Import complete
newrelic_pipeline_cloud_rule.drop_pii_data: Importing...
newrelic_pipeline_cloud_rule.drop_pii_data: Import complete

Apply complete! Resources: 3 imported, 0 added, 0 changed, 0 destroyed.

状態から古いドロップルールをクリーンアップする

インポートが正常に完了したら、Terraform 状態から古いnewrelic_nrql_drop_ruleリソースを削除する必要があります。フェーズ 2 の CLI 出力で提供されている推奨事項を使用します。

CI/CD 環境またはローカルで、古いドロップルールごとにterraform state rmコマンドを実行します。

bash

$terraform state rm newrelic_nrql_drop_rule.drop_debug_logs
$terraform state rm newrelic_nrql_drop_rule.drop_health_checks
$terraform state rm newrelic_nrql_drop_rule.drop_pii_data

注記

これらのコマンドは、New Relic からリソースを削除せずに、Terraform 状態からリソースを削除します。古いドロップルールは、サポート終了日 (2026 年 1 月 7 日) に New Relic から最終的に削除されますが、この手順の後は Terraform によって管理されなくなります。

移行を確認する

状態をクリーンアップした後:

出力をチェックして、すべてのインポートが正常に完了したことを確認します。
New Relic UIで、 Pipeline cloudルールがまだアクティブで機能していることを確認します。
terraform planを実行して、保留中の変更がないことを確認します (出力には「変更なし」と表示されます)。
古いドロップルールがterraform state listに表示されなくなったことを確認します。

プルリクエストをマージする

検証が完了したら、プルリクエストをマージして移行を完了します。 Terraform 設定では、 NRQLドロップルールではなく、 Pipeline cloudルールを管理するようになりました。

GitOps アプローチのトラブルシューティングのヘルプについては、検証スクリプトの問題についてはフェーズ 1 のトラブルシューティングガイド、CLI およびインポートの問題についてはフェーズ 2/3 のトラブルシューティングガイドを参照してください。

ローカル自動化プロセスは、状態ファイルに簡単にアクセスできるという事実を活用して、状態を自動的に更新し、新しいルールを生成してインポートし、非推奨のリソースをクリーンアップするという 3 つの連続したステップに合理化されています。

このステップでは、 New Relic CLI を使用して、Terraform ワークスペース内のすべてのドロップルールを自動的に識別し、対応するPipeline cloudマッピングで Terraform の状態を更新します。

Terraformワークスペースに移動する

ターミナルを開き、 newrelic_nrql_drop_ruleリソースを含む Terraform 設定ファイルを含むディレクトリに移動します。

bash

$cd /path/to/your/terraform/workspace

New Relic CLI 更新コマンドを実行する

次のコマンドを実行して、Terraform の状態を更新します。

bash

$newrelic migrate nrqldroprules tf-update

このコマンドは自動的に次の操作を実行します。

Terraform ワークスペースをスキャンして、すべてのnewrelic_nrql_drop_ruleリソースを識別します。
これらのリソースに対してterraform planおよびterraform apply操作を実行します。
各ドロップルールのpipeline_cloud_rule_entity_id属性を使用して、Terraform 状態ファイルを更新します。

状態の更新を確認する

コマンドが完了すると、Terraform 状態ファイルにドロップルールとPipeline cloudルール間のマッピングが含まれるようになります。これは、自分の状態を確認することで確認できます。

bash

$terraform show -json | grep pipeline_cloud_rule_entity_id

出力には、各ドロップルールのpipeline_cloud_rule_entity_id値が表示されます。これにより、状態ファイルが正常に更新されたことが確認されます。次のステップで、CLI はこれらの値を自動的に読み取ります。

New Relic CLIのインポート生成コマンドを実行する

Terraform ワークスペースディレクトリで、次のコマンドを実行します。

bash

$newrelic migrate nrqldroprules tf-importgen

このコマンドは自動的に次の操作を実行します。

ドロップルールリソースにpipeline_cloud_rule_entity_id値が含まれていることを検証します。
各Pipeline cloudルールのインポートブロックを生成します。
terraform plan -generate-config-out=generated_pipeline_rules.tfを実行してPipeline cloudルール設定を作成します。
terraform applyを実行して、 Pipeline cloudルールを Terraform 状態にインポートします。

ヒント

オプション:

--tofu: Terraform の代わりに OpenTofu を使用している場合に使用します
--fileName: インポートブロックのカスタムファイル名を指定します（デフォルトでは、インポートブロックはターミナルに出力されます）
--workspacePath: 別の Terraform ワークスペースパスを指定します (デフォルトは現在のディレクトリ)

インポート結果を確認する

コマンドが正常に完了すると、 Pipeline cloudルールが Terraform 状態にインポートされます。このコマンドは、 terraform plan -generate-config-outによって作成されたPipeline cloudルールリソース定義を含むgenerated_pipeline_rules.tfファイルを生成します。

この手順では、New Relic CLI を使用して、Terraform 状態から古い NRQL ドロップルールリソースを安全に削除します。このコマンドは、Terraform 管理からのみそれらを削除します。実際のドロップルールは、サポート終了日 (2026 年 1 月 7 日) に New Relic から最終的に削除されます。

New Relic CLIのdelistコマンドを実行する

Terraform ワークスペースディレクトリで、次のコマンドを実行します。

bash

$newrelic migrate nrqldroprules tf-delist

このコマンド:

リソースが状態からのみ削除されることを確認する安全警告を表示します
Terraform 状態からすべてのnewrelic_nrql_drop_ruleリソースを削除します
Terraform 設定ファイルをクリーンアップするための手順を説明します。

Terraform 設定をクリーンアップする

delist コマンドが完了したら、Terraform 設定ファイルが再作成されないように、コメントアウトするか、すべてのnewrelic_nrql_drop_ruleリソースブロックを削除する必要があります。

移行を確認する

設定ファイルをクリーンアップした後、移行を確認します。

bash

$# Confirm Pipeline cloud rules are in state
$terraform state list | grep pipeline_cloud_rule
$
$# Confirm old drop rules are removed from state
$terraform state list | grep nrql_drop_rule
$
$# Verify no pending changes
$terraform plan

成功した場合、 terraform planは「変更なし」と表示されます。

ローカル Terraform アプローチのトラブルシューティングのヘルプについては、CLI コマンドとインポートの問題に関するローカル Terraform トラブルシューティングガイドを参照してください。

この機械翻訳は、参考として提供されています。

ドロップルールからPipeline cloudルールに移行する

重要

移行アプローチ .css-21sua1{background:none;border:none;width:0;padding:0;}

ネイティブの Terraform コマンドを使用して移行する

前提条件

移行の手順

Pipeline cloudルールIDを取得する

注記

Pipeline cloudルールをTerraform状態にインポートする

Terraform 状態から古いドロップルールリソースを削除します。

ヒント

Terraform 設定をクリーンアップする

New Relicの自動化ツールで移行する

前提条件

アプローチを選択する

ローカルTerraformの使用

移行アプローチ